So, da ich mir gedacht hab, dass man die Aufnahmeschnittstelle von
TV-Genial mal mit dem VDR verbinden sollte, hab ich mich mal rangesetzt - Und es funktioniert - (zumindest bei mir) :-).
Und an dem Ergebniss wollt ich auch andere teilhaben lassen.
Also für den ders brauch ne kleine Anleitung:
1. netcat runterladen und die nc.exe im TV-Genial Ordner abspeichern.nc11nt.zip
2. Das Script vdr.cmd im TV-Genial Ordner abspeichern
(nicht vergessen in der zweiten Zeile den Pfad anzugeben)
@ECHO OFF
SET PROGPATH=C:\Programme\TVgenial
SET TMPFILE=%PROGPATH%\tmpfile
SET TMRFILE=%PROGPATH%\tmrfile
IF "%1" == "NEWT" GOTO NEWT
IF "%1" == "DELT" GOTO DELT
IF "%1" == "CHAN" GOTO CHAN
ECHO USAGE: %0 [NEWT,DELT,CHAN] (Options) .
ECHO .
ECHO NEWT Options: .
ECHO - Channel .
ECHO - Day .
ECHO - Starttime .
ECHO - Stoptime .
ECHO - Timername .
ECHO - Summary .
ECHO .
ECHO DELT Options: .
ECHO - Channel .
ECHO - Day .
ECHO - Starttime .
ECHO - Stoptime .
ECHO .
ECHO CHAN Options: .
ECHO - Channel .
GOTO ENDE
:NEWT
ECHO NEWT 1:%2:%3:%4:%5:99:99:%6:%7 > %TMPFILE%
ECHO MESG Timer fuer %6 am %3 um %4 bis %5 programiert >> %TMPFILE%
ECHO QUIT >> %TMPFILE%
%PROGPATH%\nc server 2001 < %TMPFILE% >> %PROGPATH%\log.txt
DEL %TMPFILE%
GOTO ENDE
:DELT
ECHO LSTT > %TMPFILE%
ECHO QUIT >> %TMPFILE%
%PROGPATH%\nc server 2001 < %TMPFILE% > %TMRFILE%
DEL %TMPFILE%
FOR /F "TOKENS=1-9 DELIMS=:" %%A IN (%TMRFILE%) DO (
FOR /F "TOKENS=2 DELIMS=- " %%K IN ("%%A") DO (
IF "%2" == "%%B" (
IF "%3" == "%%C" (
IF "%4" == "%%D" (
IF "%5" == "%%E" (
ECHO DELT %%K > %TMPFILE%
ECHO MESG Timer %%K geloescht >> %TMPFILE%
ECHO QUIT >> %TMPFILE%
%PROGPATH%\nc server 2001 < %TMPFILE% >> %PROGPATH%\log.txt
DEL %TMPFILE%
)
)
)
)
)
)
DEL %TMRFILE%
GOTO ENDE
:CHAN
ECHO CHAN %2 > %TMPFILE%
ECHO MESG Schalte um auf Programm %2 >> %TMPFILE%
ECHO QUIT >> %TMPFILE%
%PROGPATH%\nc server 2001 < %TMPFILE% >> %PROGPATH%\log.txt
DEL %TMPFILE%
GOTO ENDE
:ENDE
Alles anzeigen
3. Das Configfile für die Schnittstelle (vdr.txt)
StartOffset = -300
EndOffset = 300
StartID // bitte nicht löschen / do not remove
// 0 (unbelegt)
1 = 1 // ARD Erstes Deutsches Fernsehen
2 = 2 // ZDF Zweites Deutsches Fernsehen
3 = 5 // RTL Radio Television Luxemburg
..................
..................
..................
..................
302 = unbelegt // Offener Kanal Kiel
303 = unbelegt // Offener Kanal Klinik TV
EndID
DoRecord C:\Programme\TVgenial\vdr.cmd "NEWT" i dd hhnn rrff %
DoDelete C:\Programme\TVgenial\vdr.cmd "DELT" i dd hhnn rrff
RemindCall C:\Programme\TVgenial\vdr.cmd "CHAN" i
Alles anzeigen
4. Anpassen des Configfiles (vdr.txt)
dort müssen zwischen StartID und EndID
die TV-Genial Sender ID's den Sender ID's des VDR's
zugewiesen werden.
(nähere Besschreibung gibs in der Datei "RecorderScript.txt" im TV-Genial Verzeichniss)
5. in TV-Genial unter Optionen -> Aufnahmen -> ein "Script für unbekanntes Gerät" angeben dort die "vdr.txt"
eintragen und den Haken für die Unterstützung von löschen von Timern angeben.
Und schon sollte es mit den Timer erstellen und löschen funktionieren.
Achso, die Errinnerungsfunktion wird auch unterstützt.
Frohe Weihnachten und Guten Rutsch.