awk profi gesucht für zeilenzusammenführung

#!/usr/bin/awk -f


# Feldseparator ist Tab
BEGIN {
   FS = "\t";
}


# Funktion zum Berechnen der Zeitdifferenz
# da awk Probleme mit großen Integern hat, kann man nicht erst alles auf
# Sekunden umrechnen
function difftime(zeit1, zeit2) {
  std1 = substr(zeit1,1,2);
  min1 = substr(zeit1,4,2);
  sec1 = substr(zeit1,7,2);
  msec1 = substr(zeit1,10,3);
  std2 = substr(zeit2,1,2);
  min2 = substr(zeit2,4,2);
  sec2 = substr(zeit2,7,2);
  msec2 = substr(zeit2,10,3);
  if (std2 < std1)
	std2 += 24;
  d = (((std2-std1)*60+min2-min1)*60+sec2-sec1)*1000+msec2-msec1;
  return d;
}


# Nur Ausgabe
function ausgabe(startzeit, diff, f3, f4, f5, f6) {
    print startzeit"\t"diff"\t"f3"\t"f4"\t"f5"\t"f6;
}


# Feld 2 zeigt Startzeit
# Wenn noch eine nicht abgearbeitete Startzeit da ist,
# Erst die alte ausgeben
($2 == "--->") {
  if (startzeit != "")
     ausgabe(startzeit, -1, feld3, feld4, feld5, feld6);


   startzeit = substr($1,12);
  feld3 = $3;
  feld4 = $4;
  feld5 = $5;
  feld6 = $6;
}




# Feld 2 zeigt Stopzeit
# Differenz von 0 auf 14 "korrigieren"
($2 == "<---") {
  d = difftime(startzeit, substr($1,12));
  if (d == 0)
    d = 14;
  ausgabe(startzeit, d, feld3, feld4, feld5, feld6);
  startzeit = "";
}


# Am Ende der Datei könnte noch ein unvollstaendiger Satz sein.
END {
  if (startzeit != "")
     ausgabe(startzeit, -1, feld3, feld4, feld5, feld6);
}