epgd - tvmovie.xsl - Herstellungsland

Saman · 4. Mai 2014

Moin,

da mir die Kürzel für die Länder nicht gefallen, habe ich mal damit angefangen:

Code

<xsl:if test="string-length(Herstellungsland)">
            <xsl:choose>
              <xsl:when test="Herstellungsland = 'D'"><country>Deutschland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'A'"><country>Österreich</country></xsl:when>
              <xsl:when test="Herstellungsland = 'B'"><country>Belgien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'E'"><country>Spanien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'F'"><country>Frankreich</country></xsl:when>
              <xsl:when test="Herstellungsland = 'I'"><country>Italien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'J'"><country>Japan</country></xsl:when>
              <xsl:when test="Herstellungsland = 'N'"><country>Norwegen</country></xsl:when>
              <xsl:when test="Herstellungsland = 'P'"><country>Portugal</country></xsl:when>
              <xsl:when test="Herstellungsland = 'S'"><country>Schweden</country></xsl:when>
              <xsl:when test="Herstellungsland = 'CH'"><country>Schweiz</country></xsl:when>
              <xsl:when test="Herstellungsland = 'DK'"><country>Dänemark</country></xsl:when>
              <xsl:when test="Herstellungsland = 'GB'"><country>Großbritannien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'NL'"><country>Niederlande</country></xsl:when>
              <xsl:when test="Herstellungsland = 'PL'"><country>Polen</country></xsl:when>
              <xsl:when test="Herstellungsland = 'AUS'"><country>Australien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'CHN'"><country>China</country></xsl:when>
              <xsl:when test="Herstellungsland = 'FIN'"><country>Finnland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'IND'"><country>Indien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'IRL'"><country>Irland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'ISL'"><country>Island</country></xsl:when>
              <xsl:when test="Herstellungsland = 'ISR'"><country>Israel</country></xsl:when>
              <xsl:when test="Herstellungsland = 'LUX'"><country>Luxemburg</country></xsl:when>
              <xsl:when test="Herstellungsland = 'RUS'"><country>Russland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'D/A'"><country>Deutschland/Österreich</country></xsl:when>
              <xsl:when test="Herstellungsland = 'D/F'"><country>Deutschland/Frankreich</country></xsl:when>
              <xsl:when test="Herstellungsland = 'D/I'"><country>Deutschland/Italien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'A/D'"><country>Österreich/Deutschland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'F/D'"><country>Frankreich/Deutschland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'I/D'"><country>Italien/Deutschland</country></xsl:when>
              <xsl:when test="Herstellungsland = 'F/I'"><country>Frankreich/Italien</country></xsl:when>
              <xsl:when test="Herstellungsland = 'I/F'"><country>Italien/Frankreich</country></xsl:when>
              <xsl:otherwise><country><xsl:value-of select="Herstellungsland"/></country></xsl:otherwise>
            </xsl:choose>
          </xsl:if>

Alles anzeigen

Es fehlen noch einige Länder, aber schon so ergeben sich diverse Kombinationen.
Alle benötigt man sicher nicht, aber rein aus Interesse:
Das kann doch bestimmt auch intelligenter gelöst werden....

CKone · 4. Mai 2014

müsstest den String am "/" splitten und dann jedes einzelne Element da reinschieben um es wieder mit den Klartextnamen zusammenzubauen

Bin mir aber nicht sicher ob die Spaltenbreite auf der DB dafür vorgesehen ist, und wenn die zu schmal ist dann ist sie auch in allen Plugins und dem Daemon zu klein definiert...

wenns gefällt

Christian

Saman · 4. Mai 2014

Ich hatte auf einen etwas konkreteren Tipp gehofft , aber ok

Ein paar Filme mit zwei Länder kammen hier schon im EPG, dafür scheint es also noch zu passen.
Die 'Zweier' reichen mir dann auch schon...

3PO · 4. Mai 2014

Wäre es nicht sinnvoller, das im View zu machen?

Saman · 4. Mai 2014

Im View benutze ich das Land am mehreren Stellen, da erschien mir das so herum am einfachsten.
Ausserdem werden Sachen wie die Flags auch in der xsl zusammengebastel...

Was spricht denn dagegen?

3PO · 4. Mai 2014

Zitat von Saman

[...] Was spricht denn dagegen?

Die Anzeige in der "Kanalanzeige"

Saman · 4. Mai 2014

Das Argument zählt dann aber für beide Seiten, denn genau das will ich ja haben

3PO · 4. Mai 2014

Nun, solange es nur DU auf DEINEM System so haben willst, soll er mir egal sein.
Ich für meinen Teil, möchte eine Anzeige, bei einer Gemeinschaftsproduktion so nicht haben:

Spielfilm (Deutschland/Österreich/Schweiz/Frankreich 2014)

Saman · 4. Mai 2014

Zitat von Saman

Die 'Zweier' reichen mir dann auch schon...

3PO · 4. Mai 2014

Zitat von Saman

Die 'Zweier' reichen mir dann auch schon...

Nun, wie auch immer...

Ich will es jedenfalls nicht haben.

BTW: Bei derzeit 193 Ländern, ergibt das bei den "Zweiern" ~37000 Kombinationsmöglichkeiten. - Viel Spaß, bei basteln der *.xlt.

Saman · 4. Mai 2014

Ja, das sind einige
Darum ja Eingangs die Frage nach einer intelligenteren Lösung...
Aber ich schätze auch, das mit 50 Ländern ca 95% der real vorkommenden Möglichkeiten abgedeckt wären.

TheChief · 4. Mai 2014

Da müsstest Du Dir sowas in die Richtung bauen.

http://www.stylusstudio.com/xsllist/200401/post00510.html

Erst splitten, dann ersetzen.

3PO · 4. Mai 2014

Also ich denke mal, dass ich 98% der Länderkürzel auswendig kenne und sollte ich doch mal eines nicht kennen und solle mich es interessieren, dann schaue ich halt HIER nach.

CKone · 4. Mai 2014

Zitat von Saman

Im View benutze ich das Land am mehreren Stellen, da erschien mir das so herum am einfachsten.
Ausserdem werden Sachen wie die Flags auch in der xsl zusammengebastel...

Was spricht denn dagegen?

das das Feld nur 50 Zeichen breit ist

Kannst du besser im View machen wenn du es unbedingt bei dir haben möchtest

Christian

Saman · 5. Mai 2014

Moin,

Zitat von TheChief

Da müsstest Du Dir sowas in die Richtung bauen.

http://www.stylusstudio.com/xsllist/200401/post00510.html

Erst splitten, dann ersetzen.

danke für den Link. Mit der Funktion müsste was zu machen sein.
Die notwendige Logik habe ich auch verstanden, aber die Syntax beim xsl...

TheChief · 5. Mai 2014

Zitat von Saman

Moin,

danke für den Link. Mit der Funktion müsste was zu machen sein.
Die notwendige Logik habe ich auch verstanden, aber die Syntax beim xsl...

Ist halt Gefummel, hab mich sonst auch noch nie damit beschäftigt. Bei XSLT 2.0 gibts wohl auch eine tokenize-Funktion, wird aber glaube ich von epgd nicht unterstützt.

Siehe hier: http://stackoverflow.com/quest…/xsl-how-to-split-strings

CKone · 5. Mai 2014

für XSLT 2.0 musst du erstmal fettes Java Paket installieren - geht alles auch mit 1.0, ist halt wie du sagst alles etwas mehr Arbeit...

Christian

Saman · 5. Mai 2014

So, der Groschen ist gefallen

Code

<xsl:if test="string-length(Herstellungsland)">
            <xsl:variable name="country">
              <xsl:call-template name="Laender">
                <xsl:with-param name="str" select="concat(Herstellungsland,'/')"/>
              </xsl:call-template>
            </xsl:variable>
            <xsl:choose>
              <xsl:when test="string-length($country) &lt; 30"><country><xsl:value-of select="$country" /></country></xsl:when>
              <xsl:otherwise><country><xsl:value-of select="Herstellungsland" /></country></xsl:otherwise>
            </xsl:choose>
          </xsl:if>

Alles anzeigen

Code

<xsl:template name="Laender">
  <xsl:param name="str" select="."/>
  <xsl:variable name="part" select="substring-before($str, '/')" />
  <xsl:if test="string-length($part)">
    <xsl:choose>
      <xsl:when test="$part = 'D'"><xsl:text>Deutschland</xsl:text></xsl:when>
      <xsl:when test="$part = 'A'"><xsl:text>Österreich</xsl:text></xsl:when>
      <xsl:when test="$part = 'B'"><xsl:text>Belgien</xsl:text></xsl:when>
      <xsl:when test="$part = 'E'"><xsl:text>Spanien</xsl:text></xsl:when>
      <xsl:when test="$part = 'F'"><xsl:text>Frankreich</xsl:text></xsl:when>
      <xsl:when test="$part = 'I'"><xsl:text>Italien</xsl:text></xsl:when>
      <xsl:when test="$part = 'J'"><xsl:text>Japan</xsl:text></xsl:when>
      <xsl:when test="$part = 'N'"><xsl:text>Norwegen</xsl:text></xsl:when>
      <xsl:when test="$part = 'P'"><xsl:text>Portugal</xsl:text></xsl:when>
      <xsl:when test="$part = 'S'"><xsl:text>Schweden</xsl:text></xsl:when>
      <xsl:when test="$part = 'CH'"><xsl:text>Schweiz</xsl:text></xsl:when>
      <xsl:when test="$part = 'DK'"><xsl:text>Dänemark</xsl:text></xsl:when>
      <xsl:when test="$part = 'GB'"><xsl:text>Großbritannien</xsl:text></xsl:when>
      <xsl:when test="$part = 'GR'"><xsl:text>Griechenland</xsl:text></xsl:when>
      <xsl:when test="$part = 'IR'"><xsl:text>Iran</xsl:text></xsl:when>
      <xsl:when test="$part = 'NL'"><xsl:text>Niederlande</xsl:text></xsl:when>
      <xsl:when test="$part = 'NZ'"><xsl:text>Neuseeland</xsl:text></xsl:when>
      <xsl:when test="$part = 'PL'"><xsl:text>Polen</xsl:text></xsl:when>
      <xsl:when test="$part = 'SA'"><xsl:text>Südafrika</xsl:text></xsl:when>
      <xsl:when test="$part = 'UA'"><xsl:text>Ukraine</xsl:text></xsl:when>
      <xsl:when test="$part = 'ARG'"><xsl:text>Argentinien</xsl:text></xsl:when>
      <xsl:when test="$part = 'AUS'"><xsl:text>Australien</xsl:text></xsl:when>
      <xsl:when test="$part = 'CAM'"><xsl:text>Kamerun</xsl:text></xsl:when>
      <xsl:when test="$part = 'CDN'"><xsl:text>Kanada</xsl:text></xsl:when>
      <xsl:when test="$part = 'CHN'"><xsl:text>China</xsl:text></xsl:when>
      <xsl:when test="$part = 'COR'"><xsl:text>Südkorea</xsl:text></xsl:when>
      <xsl:when test="$part = 'FIN'"><xsl:text>Finnland</xsl:text></xsl:when>
      <xsl:when test="$part = 'IND'"><xsl:text>Indien</xsl:text></xsl:when>
      <xsl:when test="$part = 'IRL'"><xsl:text>Irland</xsl:text></xsl:when>
      <xsl:when test="$part = 'ISL'"><xsl:text>Island</xsl:text></xsl:when>
      <xsl:when test="$part = 'ISR'"><xsl:text>Israel</xsl:text></xsl:when>
      <xsl:when test="$part = 'KAS'"><xsl:text>Kasachstan</xsl:text></xsl:when>
      <xsl:when test="$part = 'LUX'"><xsl:text>Luxemburg</xsl:text></xsl:when>
      <xsl:when test="$part = 'RUS'"><xsl:text>Russland</xsl:text></xsl:when>
      <xsl:when test="$part = 'LETT'"><xsl:text>Lettland</xsl:text></xsl:when>
      <xsl:otherwise><xsl:value-of select="$part" /></xsl:otherwise>
    </xsl:choose>
  </xsl:if>
  <xsl:variable name="rest" select="substring-after($str, '/')"/>
  <xsl:if test="string-length($rest)">
    <xsl:text>/</xsl:text>
    <xsl:call-template name="Laender">      
      <xsl:with-param name="str" select="$rest"/>
    </xsl:call-template>
  </xsl:if>
</xsl:template>

Alles anzeigen

Wie prophezeit gab es zuerst auch mal so was

Code

Warning, size of 50 for 'country' exeeded [Belgien/Frankreich/Deutschland/Spanien/Großbritannien]

darum dann einfach das

Code

<xsl:when test="string-length($country) &lt; 30">

(Wer die 'Dreier' noch abdecken möchte, erhöht hier auf 40.)

und noch ein Link zum Thema: http://de.selfhtml.org/xml/darstellung/xsltelemente.htm

CKone · 5. Mai 2014

ja prina, geht doch

wenn man es im View nur "virtuell" mapped ist man halt nicht an die Spaltenbegrenzung gebunden - dem vdr ist es wurscht...

Christian

epgd - tvmovie.xsl - Herstellungsland

Jetzt mitmachen!

Teilen

Benutzer online in diesem Thema