[solved] sed/grep Ersatz , wenns um mehr als ne Zeile geht ?

Hi HJS,

Zitat

Original von hjs
Jemand ne Idee oder Tip ?
HJS

Ich benutz ja für solche Sachen immer wieder gerne awk, Gewohnheit eben...
Perl würde sich auch anbieten, aber oft lassen sich probleme mit einem kleinen stückchen awk-code lösen und damit eben auch in ein script integrieren.

Hier ein kleines Beispiel. Geht sicher noch kompakter, aber so isses übersichtlicher...

$ cat example.awk
BEGIN { trigger = 0; }
/anfang/ { trigger = 1; }
/ende/ { trigger = 0; print $0; }
// { if (trigger == 1) print $0; }


$ cat datei
liesst
alle
zeilen
der
reihe
nach
von
anfang
bis
ende


$ awk -f example.awk datei
anfang
bis
ende

BTW: verkraftet soweit ich weiss auch Steuerzeichen...

Noch ne kleine Kurzanleitung zum Beispiel:

BEGIN {} - dieser Code wird ausgeführt bevor mit der eigentlichen Verarbeitung begonnen wird.

END {} - dieser Code wird ausgeführt nachdem die eigentlichen Verarbeitung beendet wurde.

Alle anderen Code-Stücke werden auf jede Zeile angewendet, auf die der "Selektor" passt.

// {} - die beiden Slashes am Anfang sagen, dass dieser Code auf alle Zeilen angewendet wird (das zwischen den Slashes soll eine regex sein... ).

/anfang/ {} - dieser Code wird nur auf Zeilen angewendet, in denen der String "anfang" vorkommt

/ende/ {} - dito nur mit "ende"

Die regex, die ich jetzt heir verwendet habe sind natürlich sehr trivial. Man kann dort auch komplexeres definieren. Was regex halt so hergibt...

In den Klammern gibts dann die Möglichkeit mit dem Inhalt der Zeile was zu machen, z.B. print (Ausgabe) von $0 (der ganzen Zeile). Es gibt noch weitere Build-in Variables, die aber alle in der awk-manpage ganz gut dokumentiert sind.

Zitat

Original von hjs
Hehe - da sollte ich mir ne deutsche Übersetzung suchen , sonst lauf ich mit meinem begrenzten Englisch Vokabular direkt vor die Wand .

Vielleicht wird dir HIER etwas geholfen

Zitat

Originally posted by Holger D.
Perl würde sich auch anbieten

ich würd ruby den Vortritt lassen

Ok, damit hier sed nicht ganz zu kurz kommt: Ein wenig sed-Magie. Sed kann durchaus auch mit mehrzeiligen Textpassagen arbeiten, auch wenn manches doch ein wenig Grübeln erfordert.

Ausgehend von folgendem Text:

eins xxx 1
zwei xxx 2
drei xxx 3
vier xxx 4
fünf xxx 5
sechs xxx 6
sieben xxx 7

kann man so z.b. nur in den Zeilen drei bis vor sechs eine Aktion durchführen:

/^drei/ {
  :loop
  s/xxx/***/
  n
  /^sechs/!b loop
  }

Die dazu gehörige Ausgabe:
eins xxx 1
zwei xxx 2
drei *** 3
vier *** 4
fünf *** 5
sechs xxx 6
sieben xxx 7

Will man dagegen richtig zeilenübergreifend arbeiten, kann man auch mehrere Zeilen zusammen sammeln:

/^drei/ {
  :loop
  N
  /\nsechs/!b loop
  s/drei.*sechs/drei-bis-sechs/g
  }

Die dazu gehörige Ausgabe:
eins xxx 1
zwei xxx 2
drei-bis-sechs xxx 6
sieben xxx 7

Weitere interessante Spielmöglichkeiten bietet der 'hold space', ein Zwischenspeicher, in dem man einige Zeilen zwischenlagern kann, für spätere Verwendung:

/^drei/h
/^sechs/ {
  x
  G
  s/^drei\(.*\)\nsechs\(.*\)/drei-bis-sechs\1\2/
  }

Die dazu gehörige Ausgabe:
eins xxx 1
zwei xxx 2
drei xxx 3
vier xxx 4
fünf xxx 5
drei-bis-sechs xxx 3 xxx 6
sieben xxx 7

Und noch ein letzter: Kann man wohl die Zeilen drei und sechs vertauschen? Man kann:

/^drei/ {
  :loop
  N
  /\nsechs/!b loop
  h
  s/.*\n//p
  g
  s/^[^\n]*\n\(.*\)\n[^\n]*$/\1/p
  g
  s/^\([^\n]*\)\n.*/\1/
  }

Die dazu gehörige Ausgabe:
eins xxx 1
zwei xxx 2
sechs xxx 6
vier xxx 4
fünf xxx 5
drei xxx 3
sieben xxx 7

Sed ist halt weit mächtiger, als es auf den ersten Blick scheint. Viel Spaß beim weiteren Experimentieren!

Gruß,

Udo

So lange es pro Zeile nur einen solchen Text gibt, ist das noch recht einfach:

/<hier-gehts-los>/!d
s/.*<hier-gehts-los>//
:loop
/<hier-ist-ende>/ !{
  N
  b loop
  }
s/<hier-ist-ende>.*//

Nach dem letzten s/ kann man dann sogar noch weiter mit dem erkannten Block arbeiten.

Leider legt sich der Code auf die Nase, wenn mehrere interessante Blöcke in einer Zeile sind. (Stichwort greedy matching.)
Da wäre es dann schon das einfachste, in einem Vorlauf erst mal vor <hier-gehts-los> und nach <hier-ist-ende> zusätzliche Zeilenumbrüche einzubauen.

Gruß,

Udo